Edukiak

# AGGREGATE funtzioa

Funtzio honek barrutian egindako kalkuluen emaitza agregatua ematen du. Behean zerrendatutako agregazio-funtzioak erabili daitezke. Agregazio-funtzioak ahalbidetzen du ezkutuko errenkadak, erroreak SUBOTAL eta beste AGGREGATE funtzio batzuen emaitzak ez ikustea kalkulua egitean.

AGGREGATE funtzioa iragazki automatikoa aktibatuta duten datu-barruti bertikalei aplikatzen zaie. Iragazki automatikoa aktibatuta ez badago, funtzio-emaitzaren birkalkulatze automatikoak ez du funtzionatuko berriki ezkutatutako errenkadetarako. Printzipioz ez dago pentsatuta barruti horizontalekin funtzionatzeko, baina hala ere, haiei ere aplikatu ahal zaie, baina mugekin. Datu-barruti horizontalei aplikatutako AGGREGATE funtzioak ez du onartzen zutabeak ezkutatzea, baina hala ere ongi ez ikusten ditu errenkadan kapsulatutako SUBTOTAL funtzioaren eta beste AGGREGATE funtzio batzuen erroreak eta emaitzak.

### Sintaxia

AGGREGATE(Funtzioa; Aukera; Zenbakia 1[; Zenbakia 2][; ... ;[Zenbakia 253]])

edo

AGGREGATE(Funtzioa; Aukera; Matrizea[; k])

Funtzioa (derrigorrezko argumentua). Funtzio baten indizea edo 1 eta 19 arteko balioa duen gelaxka baten erreferentzia. Balioen esanahia hurrengo taulan dago zehaztuta.

Funtzio-indizea | Aplikatutako funtzioa
--- | ---
1 | AVERAGE
2 | COUNT
3 | COUNTA
4 | MAX
5 | MIN
6 | PRODUCT
7 | STDEV.S
8 | STDEV.P
9 | SUM
10 | VARP
11 | VARP
12 | MEDIAN
13 | MODE.SNGL
14 | LARGE
15 | SMALL
16 | PERCENTILE.INC
17 | QUARTILE.INC
18 | PERCENTILE.EXC
19 | QUARTILE.EXC

For Integer arguments, non-integer values are truncated to Integer.

Aukera (derrigorrezko argumentua). AUkera baten indizea edo 0 eta 7 arteko balioa duen gelaxka baten erreferentzia. Funtzioak barrutian zer ez ikusi behar duen zehazten du.

Aukera-indizea | Aukera aplikatuta
--- | ---
0 | Ez ikusi SUBTOTAL habiaratuak eta AGGREGATE funtzioak soilik
1 | Ez ikusi ezkutuko errenkadak, eta SUBTOTAL habiaratuak eta AGGREGATE funtzioak soilik
2 | Ez ikusi erroreak, SUBTOTAL habiaratuak eta AGGREGATE funtzioak soilik
3 | Ez ikusi ezkutuko errenkadak, erroreak, SUBTOTAL habiaratuak eta AGGREGATE funtzioak soilik
4 | Ez ezikusi ezer
5 | Ezikusi ezkutatutako errenkadak besterik ez
6 | Ezikusi erroreak besterik ez
7 | Ez ikusi ezkutuko errenkadak eta erroreak

For Integer arguments, non-integer values are truncated to Integer.

Zenbakia 1: Derrigorrezko argumentua. Zenbakizko lehen argumentua (barrutia funtzioaren barruan balio-zerrenda batekin ezartzen bada) edo hura daukan gelaxka baten erreferentzia.

Zenbakia 2, 3, ...: Aukerako argumentua. Zenbakizko argumentu bat edo gelaxka baten erreferentzia (253 argumentu arte). Balio agregatua kalkulatuko zaien balioak.

Matrizea: Derrigorrezko argumentua. Matrizea barrutiaren mugaren arabera, izendun barrutiaren izena erabilita edo zutabe-etiketaren arabera zehaztu daiteke.

Zutabe-etiketak erabiltzeko, "Automatikoki bilatu zutabe- eta errenkada-etiketak" funtzioak gaituta egon behar du.

k: Derrigorrezko argumentua honako funtzioetarako: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC. Zenbakizko argumentu bat da, funtzio horien bigarren argumentu gisa erabiliko dena.

### Adibideak

| A | B | C
1 | BatZutabea | BiZutabea | HiruZutabea
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #BALIOA! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
Returns maximum value for the range A2:A9 = 34.

=AGGREGATE(9;5;A5:C5)
: A5:C5 barrutiaren batuketa ematen du, alegia 29, baita zenbait zutabe ezkutatuta badaude ere.

=AGGREGATE(9;5;B2:B9):
B zutabearen batuketa ematen du (B = 115). Edozein errenkada ezkutatuta badago, funtzioak ez du balio hori kontuan izango; adibidez, 7. errenkada ezkutatuta badago, funtzioak 95 emango du.

Funtzioa 3D barruti batekin aplikatu behar bada, honako adibideak hori nola egin erakusten du.

=AGGREGATE(13;3;Orria.B2:B9:Orria3.B2:B9)
Funtzioak (datu berak dituzten) 1. orritik 3. orrira arteko bigarren zutabeen balioen moda ematen du = 8.

Gelaxka baten edo barruti baten erreferentzia erabili daiteke formulako argumentu guztietan. Hurrengo adibideak erakusten du horrek nola funtzionatzen duen. Horrez gain, erakusten du zutabe-etiketak erabili daitezkeela matrize bat zehazteko.

=AGGREGATE(E3;E5;'BatZutabea')
E3 = 13 eta E5 = 5 badira, funtzioak lehen zutabearen moda = 10 ematen du.

#### Informazio teknikoa

Funtzio hau LibreOffice 4.4 bertsiotik dago erabilgarri.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.AGGREGATE

Erlazionatutako gaiak

AGGREGATE wiki page.

AVERAGE, COUNT, COUNTA, MAX, MIN, PRODUCT, STDEV.S, STDEV.P, SUM, VAR.S, VAR.P, MEDIAN, MODE.SNGL, LARGE, SMALL, PERCENTILE.INC , QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC

Aurkitu automatikoki zutabe- eta errenkada-etiketak

Emaguzu laguntza!