CreateUnoService-funktion

Indhold

# funktionen CreateUnoService

Instantierer en Uno-tjeneste med ProcessServiceManager (proces_tjenesteadministrator).

### Syntaks:

         CreateUnoService(serviceName As String) As Object

### Returtype

Objekt

### Parametre:

Navn | Type | Beskrivelse
--- | --- | ---
serviceName | String | Tjenestenavnet. Se en liste over tilgængelige tjenester på referencesiden com::sun::star Module.

### Eksempel:

Eksemplet herunder opretter funktionen FileExists (fil_findes), der bruger tjenesten com.sun.star.ucb.SimpleFileAccess til at teste, om en given sti er en eksisterende fil.

        Function FileExists(sPath as String) As Boolean
            Dim svcSFA As Object
            Set svcSFA = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
            Dim bExists As Boolean : bExists = svcSFA.exists(sPath)
            Dim bIsFolder As Boolean : bIsFolder = svcSFA.IsFolder(sPath)
            FileExists = bExists And Not bIsFolder
        End Function ' FileExists

UNO-tjenester har udførlig online-dokumentation på webstedet api.libreoffice.org. Besøg referencesiden SimpleFileAccess Service for at få mere at vide om de metoder, der leveres af tjenesten i eksemplet herover.

### Eksempel:

Den følgende kode bruger tjenesten com.sun.star.ui.dialogs.FilePicker til at vise en åben fildialog:

    Sub Main
       fName = FileOpenDialog ("Venligst marker en fil")
       Print "Valgt fil: "+fName
    End Sub

    Function FileOpenDialog(title As String) As String
       res = com.sun.star.ui.dialogs.ExecutableDialogResults
       filepicker = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
       With filepicker
          .Title = title
          .MultiSelectionMode = True
          .appendFilter("Calc docs","*.ods;*.csv;*.123")
          .appendFilter("Writer or Base docs","*.odt;*.odb")
          .appendFilter("All files","*.*")
           If res.OK = .execute() Then
              files = .getSelectedFiles()
              FileOpenDialog=files(0)
           EndIf
       End With
    End Function ' FileOpenDialog

Relaterede emner

CreateUnoServiceWithArguments-funktion

UNO-objekter, -funktioner og -tjenester

Brug af Calc-funktioner i makroer

Støt os venligst!