ÁTLAGHATÖBB függvény
Visszaadja egy tartomány több feltételnek megfelelő összes cellájának számtani közepét. Az ÁTLAGHATÖBB függvény összeadja a logikai teszteknek megfelelő összes találatot, és elosztja ezt az összeget a kiválasztott értékek számával.
This function is available since LibreOffice 4.0.
AVERAGEIFS(Func_Range; Range1; Criterion1[; Range2; Criterion2][; … ; [Range127; Criterion127]])
Func_range – required argument. It is a range of cells, a name of a named range or a label of a column or a row containing values for calculating the mean.
Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.
Criterion1 – required argument. A string expression representing a logical condition or a cell reference to such string expression. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).
Range2 – Optional. Range2 and all the following mean the same as Range1.
Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion1.
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
Func_Range and Range1, Range2... must have the same size, otherwise the function returns err:502 - Invalid argument.
The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.
The function can have up to 255 arguments, meaning that you can specify 127 criteria ranges and criteria for them.
If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).
Ez a függvény az Open Document Format for Office Applications (OpenDocument) szabvány 1.2-es verziójának része. (ISO/IEC 26300:2-2015)
Figyelje meg a következő táblázatot
|
A
|
B
|
C
|
1
|
Termék neve
|
Eladások
|
Bevétel
|
2
|
tollbetét
|
20
|
65
|
3
|
toll
|
35
|
85
|
4
|
jegyzőkönyv
|
20
|
190
|
5
|
könyv
|
17
|
180
|
6
|
tolltartó
|
nem
|
nem
|
In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.
Egyszerű használat
=ÁTLAGHATÖBB(B2:B6;B2:B6;">=20")
Kiszámítja a B2:B6 tartomány azon értékeinek átlagát, amelyek nagyobbak, vagy egyenlőek 20-szal. A visszaadott érték 25, mert az 5. sor nem vesz részt a számításban.
=ÁTLAGHATÖBB(C2:C6;B2:B6;">=20";C2:C6;">70")
Kiszámítja a C2:C6 tartomány 70-nél nagyobb értékeinek átlagát, amelyek megfelelnek a B2:B6 20-nál nagyobb vagy egyenlő értéket tartalmazó celláinak. Visszatérési értéke 137,5, mert a második és ötödik sorok nem teljesítenek legalább egy feltételt.
Reguláris kifejezések és beágyazott függvények használata
=ÁTLAGHATÖBB(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))
Kiszámítja a C2:C6 tartomány azon értékeinek átlagát, amelyek megfelelnek a B2:B6 tartomány értékeinek, a minimális és maximális értékek kivételével. A visszatérési értéke 127,5, mert a harmadik és ötödik sorok nem teljesítenek legalább egy feltételt.
=ÁTLAGHATÖBB(C2:C6;A2:A6;"toll.*";B2:B6;"<"&MAX(B2:B6))
Kiszámítja a C2:C6 tartomány értékeinek átlagát, amelyek megfelelnek az A2:A6 tartomány "toll" kezdetű celláinak, és a B2:B6 tartomány összes cellájának a maximum kivételével. A visszatérési értéke 65, mert csak a második sor teljesíti az összes feltételt.
Hivatkozás cellára feltételként
Ha egyszerűen szeretne feltételt módosítani, akkor érdemes egy külön cellában megadni, és erre a cellára mutató hivatkozást használni az ÁTLAGHATÖBB függvény feltételében. A fenti függvény például átírható a következőképpen:
=ÁTLAGHATÖBB(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))
Ha E2 = toll, akkor a függvény a 65 értéket adja vissza, mert a cellahivatkozás az értékével lesz helyettesítve.